#######################################################################
# Admone ZSH prompt. Copyright Armaan Bhojwani. MIT licensed, see the #
# LICENSE file or https://www.opensource.org/licenses/MIT for more    #
# information. Git repo at https://codeberg.org/armaan/admone         #
#######################################################################

#
# USER CONFIGURATIONS
#

ADMONE_PROMPT_CHAR="➤"
  # ADMONE_PROMPT_CHAR="❯❯❯"
  # ADMONE_PROMPT_CHAR="$"
  # ADMONE_PROMPT_CHAR="%"
  # ADMONE_PROMPT_CHAR=">"
  # ADMONE_PROMPT_CHAR="➢"
  # ADMONE_PROMPT_CHAR="➪"
ADMONE_PRE_UPPER="╭"
ADMONE_PRE_LOWER="╰"
  # ADMONE_PRE_UPPER="┌"
  # ADMONE_PRE_LOWER="└"
ADMONE_BLOCK_SEPARATOR="─"
  # ADMONE_BLOCK_SEPARATOR="∙"
ADMONE_BLOCK_LEFT="["
ADMONE_BLOCK_RIGHT="]"
  # ADMONE_BLOCK_LEFT="{"
  # ADMONE_BLOCK_RIGHT="}"
  # ADMONE_BLOCK_LEFT="("
  # ADMONE_BLOCK_RIGHT=")"
ADMONE_VI_MODE_CURSOR="1"
  # ADMONE_VI_MODE_CURSOR="1"
ADMONE_SHOW_0_EXIT_CODE="0"
ADMONE_INCLUDE="admone-pwd;admone-git;admone-exit-code"
ADMONE_FORMAT_LOWER="%B%F{%(?.cyan.red)}"

admone-pwd() {
  echo "%F{blue}%~%f"
}
admone-git() {
  git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
  echo "%F{green}${git_branch}%f"
}
admone-exit-code() {
  ([[ $ADMONE_SHOW_0_EXIT_CODE == "1" ]] && echo "%(?,%F{cyan}%?%f,%F{red}%?%f)") ||
  echo "%(?,,%F{red}%?%f)"
}
admone-date() {
  echo $(date -I)
}
admone-12hr() {
  echo $(date +%r)
}
admone-24hr() {
  echo $(date +%T)
}
# Intergration with https://codeberg.org/armaan/zsh-command-time
admone-time() {
  echo "%F{cyan}$timer_show%f"
}

#######################################################################

#
# BACKEND
#

# Cursor shape depends on vi mode
function zle-keymap-select zle-line-init zle-line-finish {
  if [[ $ADMONE_VI_MODE_CURSOR == "1" ]]; then
    case $KEYMAP in
      vicmd)
        # Block
        print -n -- "\E]50;CursorShape=0\C-G"
        ;;
      viins|main)
        # Beam
        print -n -- "\E]50;CursorShape=1\C-G"
        ;;
    esac
    zle reset-prompt
    zle -R
  fi
}

set-prompt() {
  # Reset prompts
  upper="${ADMONE_PRE_UPPER}"
  lower="${ADMONE_PRE_LOWER}${ADMONE_FORMAT_LOWER}${ADMONE_PROMPT_CHAR}%f%b "

  # Add in functions as defined above
  NUM_FUNCS="$(echo $ADMONE_INCLUDE | grep -o ';' | wc -l)"
  for (( i = 0; i <= $NUM_FUNCS; i++ )); do
    THE_COMMAND="$(echo $ADMONE_INCLUDE | cut -d ';' -f $(($i + 1)))"
    [[ $i == 0 ]] && upper+="$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
    [[ $i == 0 ]] || upper+="$ADMONE_BLOCK_SEPARATOR$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  done

  # Add line above
  [[ -v PS1_NL ]] && echo || PS1_NL=

  PROMPT=$upper$'\n'$lower
}

# Set everything!
zle -N zle-line-init
zle -N zle-line-finish
zle -N zle-keymap-select
autoload -Uz add-zsh-hook
add-zsh-hook precmd set-prompt