#######################################################################
# Admone ZSH prompt. Copyright Armaan Bhojwani. MIT licensed, see the #
# LICENSE file or https://www.opensource.org/licenses/MIT for more    #
# information. Git repo at https://codeberg.org/armaan/admone         #
#######################################################################

#
# USER CONFIGURATIONS
#

ADMONE_PROMPT_CHAR="❯❯❯"
ADMONE_PRE_UPPER="╭ "
ADMONE_PRE_LOWER="╰ "
ADMONE_BLOCK_SEPARATOR="-"
ADMONE_BLOCK_LEFT="["
ADMONE_BLOCK_RIGHT="]"
ADMONE_VI_MODE_CURSOR="1"
ADMONE_INCLUDE="admone-pwd;admone-git;admone-exit-code;admone-time"
ADMONE_FORMAT_LOWER="%B%F{%(?.cyan.red)}"

function admone-pwd {
  echo "%F{blue}%~%f%F{240}"
}
function admone-git {
  local git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
  echo "%F{green}${git_branch//\%/%%}%f"
}
function admone-exit-code {
  echo "%(?,,%F{1}%?%F{240})"
}
function admone-date {
  echo $(date -I)
}
function admone-12hr {
  echo $(date +%r)
}
function admone-24hr {
  echo $(date +%T)
}
function admone-time {
  # Intergration with https://codeberg.org/armaan/zsh-command-time
  echo "%F{cyan}$timer_show%f"
}

#######################################################################

#
# BACKEND
#

# Cursor shape depends on vi mode
function zle-keymap-select zle-line-init zle-line-finish {
  if [[ $ADMONE_VI_MODE_CURSOR == 1 ]]; then
    case $KEYMAP in
      vicmd)
        # Block
        print -n -- "\E]50;CursorShape=0\C-G"
        ;;
      viins|main)
        # Beam
        print -n -- "\E]50;CursorShape=1\C-G"
        ;;
    esac

    zle reset-prompt
    zle -R
  fi
}

function set-prompt() {
  # Reset prompts
  upper="${ADMONE_PRE_UPPER}"
  lower="${ADMONE_PRE_LOWER}${ADMONE_FORMAT_LOWER}${ADMONE_PROMPT_CHAR}%f%b "

  # Add in functions as defined above
  NUM_FUNCS="$(echo $ADMONE_INCLUDE | grep -o ';' | wc -l)"
  for (( i = 0; i <= $NUM_FUNCS; i++ )); do
    (( val = $i + 1 ))
    THE_COMMAND="$(echo $ADMONE_INCLUDE | cut -d ';' -f $val)"
    if [[ $val == 1 ]]; then
      upper+="$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
    else
      upper+="$ADMONE_BLOCK_SEPARATOR$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
    fi
  done

  # Add line above
  [[ -v PS1_NL ]] && echo || PS1_NL=

  PROMPT=$upper$'\n'$lower
}

# Set everything!
zle -N zle-line-init
zle -N zle-line-finish
zle -N zle-keymap-select
autoload -Uz add-zsh-hook
add-zsh-hook precmd set-prompt