admone.zsh

   1 #######################################################################
   2 # Admone ZSH prompt. Copyright Armaan Bhojwani, palb91, romkatv.      #
   3 # MIT licensed, see the LICENSE file or                               #
   4 # https://www.opensource.org/licenses/MIT for more information.       #
   5 # Git repo at https://codeberg.org/armaan/admone                      #
   6 #######################################################################
   7
   8 #
   9 # USER CONFIGURATIONS
  10 #
  11
  12 ADMONE_PROMPT_CHAR="❯❯❯"
  13 ADMONE_PRE_UPPER="╭ "
  14 ADMONE_PRE_LOWER="╰ "
  15 ADMONE_BLOCK_SEPARATOR="-"
  16 ADMONE_BLOCK_LEFT="["
  17 ADMONE_BLOCK_RIGHT="]"
  18 ADMONE_INCLUDE="admone-pwd;admone-git;admone-exit-code;admone-12hr"
  19
  20 function admone-pwd {
  21   echo "%F{blue}%~%f%F{240}"
  22 }
  23 function admone-git {
  24   local git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
  25   echo "%F{green}${git_branch//\%/%%}%f"
  26 }
  27 function admone-exit-code {
  28   echo "%(?,,%F{1}%?%F{240})"
  29 }
  30
  31 function admone-date {
  32   echo $(date -I)
  33 }
  34 function admone-12hr {
  35   echo $(date +%r)
  36 }
  37 function admone-24hr {
  38   echo $(date +%x)
  39 }
  40 #######################################################################
  41
  42 #
  43 # BACKEND
  44 #
  45
  46 # Cursor shape depends on vi mode
  47 function zle-keymap-select zle-line-init zle-line-finish {
  48   case $KEYMAP in
  49     vicmd)
  50       print -n -- "\E]50;CursorShape=0\C-G"
  51       ;;
  52     viins|main)
  53       print -n -- "\E]50;CursorShape=1\C-G"
  54       ;;
  55     *)
  56       ;;
  57   esac
  58
  59   zle reset-prompt
  60   zle -R
  61 }
  62
  63 function set-prompt() {
  64   upper="%B${ADMONE_PRE_UPPER}"
  65   lower="%B${ADMONE_PRE_LOWER}%B%F{%(?.cyan.red)}${ADMONE_PROMPT_CHAR}%f%b "
  66
  67   NUM_FUNCS="$(echo $ADMONE_INCLUDE | grep -o ';' | wc -l)"
  68   REAL_NUM_FUNCS=$((NUM_FUNCS+1))
  69
  70   for (( i = 0; i <= $NUM_FUNCS; i++ )); do
  71     (( val = $i + 1 ))
  72     THE_COMMAND="$(echo $ADMONE_INCLUDE | cut -d ';' -f $val)"
  73
  74     if [[ $val == 1 ]]; then
  75       upper+="$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  76     else
  77       upper+="$ADMONE_BLOCK_SEPARATOR$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  78     fi
  79   done
  80
  81   [[ -v PS1_NL ]] && echo || PS1_NL=
  82   PROMPT=$upper$'\n'$lower
  83 }
  84
  85 zle -N zle-line-init
  86 zle -N zle-line-finish
  87 zle -N zle-keymap-select
  88 autoload -Uz add-zsh-hook
  89 add-zsh-hook precmd set-prompt