admone.zsh

   1 #######################################################################
   2 # Admone ZSH prompt. Copyright Armaan Bhojwani. MIT licensed, see the #
   3 # LICENSE file or https://www.opensource.org/licenses/MIT for more    #
   4 # information. Git repo at https://codeberg.org/armaan/admone         #
   5 #######################################################################
   6
   7 #
   8 # USER CONFIGURATIONS
   9 #
  10
  11 ADMONE_PROMPT_CHAR="➤"
  12   # ADMONE_PROMPT_CHAR="❯❯❯"
  13   # ADMONE_PROMPT_CHAR="$"
  14   # ADMONE_PROMPT_CHAR="%"
  15   # ADMONE_PROMPT_CHAR=">"
  16   # ADMONE_PROMPT_CHAR="➢"
  17   # ADMONE_PROMPT_CHAR="➪"
  18 ADMONE_PRE_UPPER="╭ "
  19 ADMONE_PRE_LOWER="╰ "
  20   # ADMONE_PRE_UPPER="┌ "
  21   # ADMONE_PRE_LOWER="└ "
  22 ADMONE_BLOCK_SEPARATOR="─"
  23   # ADMONE_BLOCK_SEPARATOR="∙"
  24 ADMONE_BLOCK_LEFT="["
  25 ADMONE_BLOCK_RIGHT="]"
  26   # ADMONE_BLOCK_LEFT="{"
  27   # ADMONE_BLOCK_RIGHT="}"
  28   # ADMONE_BLOCK_LEFT="("
  29   # ADMONE_BLOCK_RIGHT=")"
  30 ADMONE_VI_MODE_CURSOR="1"
  31 ADMONE_INCLUDE="admone-pwd;admone-git;admone-exit-code;admone-time"
  32 ADMONE_FORMAT_LOWER="%B%F{%(?.cyan.red)}"
  33
  34 function admone-pwd {
  35   echo "%F{blue}%~%f%F{240}"
  36 }
  37 function admone-git {
  38   local git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
  39   echo "%F{green}${git_branch//\%/%%}%f"
  40 }
  41 function admone-exit-code {
  42   echo "%(?,,%F{1}%?%F{240})"
  43 }
  44 function admone-date {
  45   echo $(date -I)
  46 }
  47 function admone-12hr {
  48   echo $(date +%r)
  49 }
  50 function admone-24hr {
  51   echo $(date +%T)
  52 }
  53 function admone-time {
  54   # Intergration with https://codeberg.org/armaan/zsh-command-time
  55   echo "%F{cyan}$timer_show%f"
  56 }
  57
  58 #######################################################################
  59
  60 #
  61 # BACKEND
  62 #
  63
  64 # Cursor shape depends on vi mode
  65 function zle-keymap-select zle-line-init zle-line-finish {
  66   if [[ $ADMONE_VI_MODE_CURSOR == 1 ]]; then
  67     case $KEYMAP in
  68       vicmd)
  69         # Block
  70         print -n -- "\E]50;CursorShape=0\C-G"
  71         ;;
  72       viins|main)
  73         # Beam
  74         print -n -- "\E]50;CursorShape=1\C-G"
  75         ;;
  76     esac
  77
  78     zle reset-prompt
  79     zle -R
  80   fi
  81 }
  82
  83 function set-prompt() {
  84   # Reset prompts
  85   upper="${ADMONE_PRE_UPPER}"
  86   lower="${ADMONE_PRE_LOWER}${ADMONE_FORMAT_LOWER}${ADMONE_PROMPT_CHAR}%f%b "
  87
  88   # Add in functions as defined above
  89   NUM_FUNCS="$(echo $ADMONE_INCLUDE | grep -o ';' | wc -l)"
  90   for (( i = 0; i <= $NUM_FUNCS; i++ )); do
  91     (( val = $i + 1 ))
  92     THE_COMMAND="$(echo $ADMONE_INCLUDE | cut -d ';' -f $val)"
  93     if [[ $val == 1 ]]; then
  94       upper+="$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  95     else
  96       upper+="$ADMONE_BLOCK_SEPARATOR$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  97     fi
  98   done
  99
 100   # Add line above
 101   [[ -v PS1_NL ]] && echo || PS1_NL=
 102
 103   PROMPT=$upper$'\n'$lower
 104 }
 105
 106 # Set everything!
 107 zle -N zle-line-init
 108 zle -N zle-line-finish
 109 zle -N zle-keymap-select
 110 autoload -Uz add-zsh-hook
 111 add-zsh-hook precmd set-prompt