admone.zsh

   1 #######################################################################
   2 # Admone ZSH prompt. Copyright Armaan Bhojwani. MIT licensed, see the #
   3 # LICENSE file or https://www.opensource.org/licenses/MIT for more    #
   4 # information. Git repo at https://codeberg.org/armaan/admone         #
   5 #######################################################################
   6
   7 #
   8 # USER CONFIGURATIONS
   9 #
  10
  11 ADMONE_PROMPT_CHAR="❯❯❯"
  12 ADMONE_PRE_UPPER="╭ "
  13 ADMONE_PRE_LOWER="╰ "
  14 ADMONE_BLOCK_SEPARATOR="-"
  15 ADMONE_BLOCK_LEFT="["
  16 ADMONE_BLOCK_RIGHT="]"
  17 ADMONE_VI_MODE_CURSOR="1"
  18 ADMONE_INCLUDE="admone-pwd;admone-git;admone-exit-code;admone-time"
  19 ADMONE_FORMAT_LOWER="%B%F{%(?.cyan.red)}"
  20
  21 function admone-pwd {
  22   echo "%F{blue}%~%f%F{240}"
  23 }
  24 function admone-git {
  25   local git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
  26   echo "%F{green}${git_branch//\%/%%}%f"
  27 }
  28 function admone-exit-code {
  29   echo "%(?,,%F{1}%?%F{240})"
  30 }
  31 function admone-date {
  32   echo $(date -I)
  33 }
  34 function admone-12hr {
  35   echo $(date +%r)
  36 }
  37 function admone-24hr {
  38   echo $(date +%T)
  39 }
  40 function admone-time {
  41   # Intergration with https://codeberg.org/armaan/zsh-command-time
  42   echo "%F{cyan}$timer_show%f"
  43 }
  44
  45 #######################################################################
  46
  47 #
  48 # BACKEND
  49 #
  50
  51 # Cursor shape depends on vi mode
  52 function zle-keymap-select zle-line-init zle-line-finish {
  53   if [[ $ADMONE_VI_MODE_CURSOR == 1 ]]; then
  54     case $KEYMAP in
  55       vicmd)
  56         # Block
  57         print -n -- "\E]50;CursorShape=0\C-G"
  58         ;;
  59       viins|main)
  60         # Beam
  61         print -n -- "\E]50;CursorShape=1\C-G"
  62         ;;
  63     esac
  64
  65     zle reset-prompt
  66     zle -R
  67   fi
  68 }
  69
  70 function set-prompt() {
  71   # Reset prompts
  72   upper="${ADMONE_PRE_UPPER}"
  73   lower="${ADMONE_PRE_LOWER}${ADMONE_FORMAT_LOWER}${ADMONE_PROMPT_CHAR}%f%b "
  74
  75   # Add in functions as defined above
  76   NUM_FUNCS="$(echo $ADMONE_INCLUDE | grep -o ';' | wc -l)"
  77   for (( i = 0; i <= $NUM_FUNCS; i++ )); do
  78     (( val = $i + 1 ))
  79     THE_COMMAND="$(echo $ADMONE_INCLUDE | cut -d ';' -f $val)"
  80     if [[ $val == 1 ]]; then
  81       upper+="$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  82     else
  83       upper+="$ADMONE_BLOCK_SEPARATOR$ADMONE_BLOCK_LEFT$($THE_COMMAND)$ADMONE_BLOCK_RIGHT"
  84     fi
  85   done
  86
  87   # Add line above
  88   [[ -v PS1_NL ]] && echo || PS1_NL=
  89
  90   PROMPT=$upper$'\n'$lower
  91 }
  92
  93 # Set everything!
  94 zle -N zle-line-init
  95 zle -N zle-line-finish
  96 zle -N zle-keymap-select
  97 autoload -Uz add-zsh-hook
  98 add-zsh-hook precmd set-prompt